#! /usr/bin/perl -w
# Hunt the Wumpus.
# A quick and dirty port by L. Ross Raszewski http://www.trenchcoatsoft.com
# Hunt the Wumpus is (c) 1973 by Gregory Coresun
# This port is based on a description of the game by Jason Dyer:
# https://bluerenga.blog/2019/04/03/before-adventure-part-4-hunt-the-wumpus-1973/
#
# This code is public domain.
use List::Util qw/shuffle/;
no if $] >= 5.017011, warnings => 'experimental::smartmatch';
use constant { BAT => 1,
	       PIT => 2,
};

my @map =  ( 1, 4, 7, 0, 2, 9, 1, 3, 11, 2, 4, 13, 0, 3, 5, 4, 6, 14, 5, 7, 16, 0, 6, 8, 7, 9, 17, 1, 8, 10, 9, 11, 18, 2, 10, 12, 11, 13, 19, 3, 12, 14, 5, 13, 15, 14, 16, 19, 6, 15, 17, 8, 16, 18, 10, 17, 19, 12, 15, 18 );

my $nbats = 2;
my $npits = 2;
my $narrows = 6;
my @deck; 
my %hazards;
my $wumpus;
my $location;
my $arrows;
sub initializeGame {
    @deck = ( 0..((scalar @map)/3)-1);
    @deck = shuffle(@deck);
    %hazards = ();
    $arrows = $narrows;
    $hazards{shift @deck} = BAT foreach (1..$nbats);
    $hazards{shift @deck} = PIT foreach (1..$npits);
    $wumpus = shift @deck;
    $location = @deck[int(rand(scalar @deck))];
    print <<ENDINTRO
Welcome to the cave of the Wumpus. Your mission is to kill the elusive creature.
You must hunt in the darkness as the Wumpus will flee from the slightest light.
You have $narrows crooked arrows which can be fired along any path through 
up to five chambers within the cave. 
Beware! In the dark you stand no chance at close range against the Wumpus.
Also, there are $npits deep pits in the cave, it would be folly to cross one.
There are also $nbats flocks of unusually strong bats which will carry you away.

Good Luck!

ENDINTRO
;

}
sub meetBats {
    my $nloc = $location;
    $nloc = int(rand(scalar @map)/3)
	until $nloc != $location && !($hazards{$nloc} ~~ BAT);
    $location = $nloc;
    print "You hear a flutter of bats all around you and are suddenly lifted off your feet and carried away...\n";

}

sub showRoom {
    print "You are in room $location\n";
    my $o = $location * 3;
    my ($a, $b, $c) = @map[$o, $o+1, $o+2];
    print "Tunnels lead to rooms $a, $b and $c\n";
    if ($hazards{$location} ~~ BAT) { meetBats(); return showRoom(); }
    elsif ($hazards{$location} ~~ PIT) {
	print "You plunge downward in the darkness. Whether the pit into which you have fallen is bottomless, or simply very, very deep, may be of some interest to a future spelunker, but the difference is immaterial to you personally. You have died.\n";
	return 1;
    } elsif ($location == $wumpus) {
	print "The smell of Wumpus grows strong all around you. There is a sound somewhere between a snarl and a growl, and one very brief moment of intense pain. Fortunately, the Wumpus is an efficient predator. You have died.\n";
	return 1;
    } else {
	my %response = ();
	foreach ($a, $b, $c) {
	    $response{"You smell Wumpus.\n"} = 1 if $_ == $wumpus;
	    $response{"You hear flapping.\n"} = 1 if $hazards{$_} ~~ BAT;
	    $response{"You feel a breeze.\n"} = 1 if $hazards{$_} ~~ PIT;
	}
	print join "", sort keys %response;
	return 0;
    }
}
sub moveRooms {
    my $ix = $location*3;
    my ($a, $b, $c) = @map[$ix, $ix+1, $ix+2];
    print "Move to which room? [$a, $b, $c] >";
    $location = getNumber($a, $b, $c);
    
}
sub shootArrow {
    print "Shoot through how many rooms? [1-5] >";
    my $input = getNumber(1..5);
    my @path = ();
    print "Which room? >";
    my $ix = $location*3;
    push @path, getNumber(@map[$ix..($ix+2)]);
    foreach (2..$input) {
	print "Then which room? >";
	    push @path, getNumber(0..((scalar @map)/3));
    }
    my $aloc = $location;
    foreach (@path) {
	$ix = $aloc*3;
	unless ($_==$map[$ix] || $_==$map[$ix+1] || $_==$map[$ix+2]) {
	    print "You hear your arrow strike the cave wall and deflect!\n";
	    $_ = $map[$ix+int(rand(3))];
	}
	if ($_==$location) {
	    print "You hear the briefest \"thwip!\" and ".
		"feel a sudden shock of pain. It has rebounded back ".
		"into your chest! You have died.\n";
	    return 1;
	} elsif ($_==$wumpus) {
	    print "The beast lets out a mighty howl and is slain! ".
		"Congratulations! You have killed the Wumpus!\n";
	    return 1;
	}
	$aloc = $_;
    }
    print "You hear the arrow clatter to the ground in the distance. ".
	"The Wumpus heard it as well, and you hear a scurrying as it moves ".
	"to a new hiding place.\n";
    $arrows--;
    if ($arrows <= 0) {
	print "That was your last arrow. Your hunt has ended in defeat.";
	return 1;
    }
    return 0;
}
sub mainLoop {
    initializeGame();
    while(showRoom()==0) {
	print "[S]hoot, [M]ove or [Q]uit? > ";
	my $input = getInput('SMQ');
	if ($input eq 'S') {
	    return if shootArrow();
	} elsif ($input eq'M') {
	    moveRooms();
	} else {
	    return;
	}
    }
}

sub getInput {
    my $str = shift;
    while(1) {
	my $input = <STDIN>;
	chomp $input;
	if ($input =~ m/^[$str]$/i) {
	    return uc($input);
	}
	print "Please enter one of [$str] >";
    }
}
sub getNumber {
    while(1) {
	my $input = <STDIN>;
	chomp $input;
	if ($input =~ m/^\d+$/ && grep { $input == $_ } @_) {
	    return $input;
	} 
	print "Please enter a valid number >";
    }

}
do {
    mainLoop();
    print "Play again? [Y/N] > ";
    
} while(getInput('yn') eq 'Y');

print "Goodbye!\n";